VMware服务一键启停脚本

背景介绍

很多VMware 用户可能都遇到过这样的困扰：即使不使用虚拟机，VMware的多个后台服务也会在开机时自动启动，长期占用系统资源。这些服务包括：

• VMware Authorization Service
  
• VMware DHCP Service
  
• VMware NAT Service
  
• VMware USB Arbitration Service
  
• VMware Workstation Server
  

此外，VMware相关的网络适配器（VMnet1、VMnet8）也会一直保持活跃状态。尽管通过任务管理器关闭了VMware主程序，这些后台服务依然在悄悄运行，消耗着系统资源。
脚本功能

因此简单编写了以下这个批处理脚本提供了一个简单的解决方案：

• 智能检测：自动检测当前VMware服务的运行状态
  
• 一键切换：
  
  
  
  • 如果服务正在运行，一键停止所有服务和网络适配器
    
  • 如果服务已停止，一键启动所有服务和程序
    
  
  
• 完全清理：彻底终止所有VMware相关进程
  
• 便捷操作：双击以管理员身份执行，无需手动选择
  

1. @echo off
2. setlocal enabledelayedexpansion
4. REM 设置VMware路径变量
5. set "VMWARE_PATH=D:\XXX\VMware\vmware.exe"
7. set "running_count=0"
8. set "total_services=5"
10. REM 检查VMware Authorization Service状态
11. for /f "skip=3 tokens=4" %%i in ('sc query "VMAuthdService"') do set "zt=%%i" & goto :check_auth
12. :check_auth
13. if /i "%zt%"=="RUNNING" (
14.     echo 服务VMware Authorization Service正在运行
15.     set /a running_count+=1
16. ) else (
17.     echo 服务VMware Authorization Service已停止
18. )
20. REM 检查VMware DHCP Service状态
21. for /f "skip=3 tokens=4" %%i in ('sc query "VMnetDHCP"') do set "zt=%%i" & goto :check_dhcp
22. :check_dhcp
23. if /i "%zt%"=="RUNNING" (
24.     echo 服务VMware DHCP Service正在运行
25.     set /a running_count+=1
26. ) else (
27.     echo 服务VMware DHCP Service已停止
28. )
30. REM 检查VMware NAT Service状态
31. for /f "skip=3 tokens=4" %%i in ('sc query "VMware NAT Service"') do set "zt=%%i" & goto :check_nat
32. :check_nat
33. if /i "%zt%"=="RUNNING" (
34.     echo 服务VMware NAT Service正在运行
35.     set /a running_count+=1
36. ) else (
37.     echo 服务VMware NAT Service已停止
38. )
40. REM 检查VMware USB Arbitration Service状态
41. for /f "skip=3 tokens=4" %%i in ('sc query "VMUSBArbService"') do set "zt=%%i" & goto :check_usb
42. :check_usb
43. if /i "%zt%"=="RUNNING" (
44.     echo 服务VMware USB Arbitration Service正在运行
45.     set /a running_count+=1
46. ) else (
47.     echo 服务VMware USB Arbitration Service已停止
48. )
50. REM 检查VMware Workstation Server状态
51. for /f "skip=3 tokens=4" %%i in ('sc query "VMwareHostd"') do set "zt=%%i" & goto :check_hostd
52. :check_hostd
53. if /i "%zt%"=="RUNNING" (
54.     echo 服务VMware Workstation Server正在运行
55.     set /a running_count+=1
56. ) else (
57.     echo 服务VMware Workstation Server已停止
58. )
60. echo 当前有 !running_count! 个VMware服务在运行（共 %total_services% 个）
62. REM 根据服务状态自动决定启动或停止
63. if !running_count! GTR 0 (
64.     echo 检测到VMware服务正在运行，准备停止所有服务...
65.    
66.     echo 正在禁用服务...
67.     net stop "VMAuthdService" 2>nul
68.     net stop "VMnetDHCP" 2>nul
69.     net stop "VMware NAT Service" 2>nul
70.     net stop "VMUSBArbService" 2>nul
71.     net stop "VMwareHostd" 2>nul
72.    
73.     echo 正在禁用网络连接...
74.     netsh interface set interface "VMware Network Adapter VMnet1" disable 2>nul
75.     netsh interface set interface "VMware Network Adapter VMnet8" disable 2>nul
76.     echo 网络连接VMware Network Adapter VMnet1、VMware Network Adapter VMnet8禁用成功
77.    
78.     echo 正在结束进程...
79.     taskkill /F /IM vmware-authd.exe /T 2>nul
80.     taskkill /F /IM vmnetdhcp.exe /T 2>nul
81.     taskkill /F /IM vmnat.exe /T 2>nul
82.     taskkill /F /IM vmware-usbarbitrator64.exe /T 2>nul
83.     taskkill /F /IM vmware-hostd.exe /T 2>nul
84.     taskkill /F /IM vmware-tray.exe /T 2>nul
85.     taskkill /F /IM vmware.exe /T 2>nul
86.    
87.     echo VMware服务已全部停止！
88. ) else (
89.     echo 检测到VMware服务已停止，准备启动所有服务...
90.    
91.     echo 正在启用服务...
92.     net start "VMAuthdService" 2>nul
93.     net start "VMnetDHCP" 2>nul
94.     net start "VMware NAT Service" 2>nul
95.     net start "VMUSBArbService" 2>nul
96.     net start "VMwareHostd" 2>nul
97.    
98.     echo 正在启用网络连接...
99.     netsh interface set interface "VMware Network Adapter VMnet1" enable 2>nul
100.     netsh interface set interface "VMware Network Adapter VMnet8" enable 2>nul
101.     echo 网络连接VMware Network Adapter VMnet1、VMware Network Adapter VMnet8启动成功
102.    
103.     echo 正在启动VMware...
104.     start "" "%VMWARE_PATH%"
105.    
106.     echo VMware服务已全部启动！
107. )
109. timeout /t 3
110. exit

复制代码

使用方法

• 复制下载脚本并根据自己的VMware安装路径修改变量VMWARE_PATH
  
• 双击以管理员身份执行
  
• 脚本将自动检测VMware服务状态并执行相应操作
  

这个脚本特别适合那些像我一样不希望它一直占用系统资源的用户。

来源：程序园用户自行投稿发布，如果侵权，请联系站长删除
免责声明：如果侵犯了您的权益，请联系站长，我们会及时删除侵权内容，谢谢合作！