登录/ 注册
 找回密码
 立即注册
关闭

CSDN热搜

程序园 精品问答 技术交流 资源下载
返回列表 发新帖
首页 › 业界区 › 业界 ›一步一步学习使用LiveBindings（14）TListView进阶使用 ...

一步一步学习使用LiveBindings（14）TListView进阶使用（2），打造天气预报程序

忙贬 2025-8-16 07:13:11
在《一步一步学习使用LiveBindings（12）》课中，非常详细的介绍了如何在设计时手工的编辑DynamicAppearance类型的项，大大方便了构建自定义的列表项。但是很多情况下，仍然要面对编程创建列表项的情形，特别是当要实现自定义的列表项时，将不得不面对编程创建列表项的挑战。
注意：更理想的自定义列表项的的方法是为 TListView 组件编写自定义样式；将组件放入一个包中，安装到 IDE 中，然后从对象检查器窗口使用它。这样就可以在多个项目中重复的使用。
这一课将主要介绍如下内容：

  • 使用TRestClient从远端服务器获取服务。
  • 解析JSON，根据JOSN的内容，创建TListViewItem。
  • 根据JSON的内容，生成不同的列表项呈现。
这一课将是创建自定义列表项的基础，掌握了这一课的内容，基本对TListView，也就没有大的问题了。
1. 关于天气预报网站OpenWeatherMap：

OpenWeatherMap 是一个提供全球天气数据的知名服务平台，主要面向开发者、企业和个人用户。以下是它的核心特点：

  • 实时与预报天气数据
    提供实时天气、分钟级降水预报、短期（5天）及长期（16天）预报，甚至历史天气数据。
    覆盖全球任意坐标（包括偏远地区），数据来源自气象站、卫星和雷达。
  • 多样化的数据接口
    通过 REST API 和 地图图层API 提供数据，支持JSON/XML格式。
    免费层有限制（如60次/分钟调用），付费层可获取更高精度（如小时级降水）和更多功能。
  • 丰富的天气指标
    温度、湿度、风速、气压、降水、紫外线指数等。
    特殊数据如空气质量（PM2.5）、花粉浓度、自然灾害警报等需订阅高级服务。
  • 应用场景广泛
    开发者常用其API集成到移动应用、网站或IoT设备（如智能家居）。
    企业用户可能用于物流、农业或旅游行业的天气分析。
  • 数据可视化工具
    提供交互式地图，可叠加云层、降水等实时天气图层。
  • 费用与权限
    免费方案 适合小规模测试（如1,000次/天API调用）。
    商业用途需选择付费计划（如企业级数据或高频率访问）。
  • 数据覆盖与更新
    覆盖40多万个城市，部分数据更新频率可达每分钟。
    注意事项
    免费数据可能不如专业气象机构精确，付费服务（如History API或Agro API）更适合高要求场景。
    使用前需注册获取API Key，并遵守其条款（如注明数据来源）。
    如果需要替代方案，可考虑 WeatherAPI、AccuWeather 或 ClimaCell（现为Tomorrow.io）。具体选择取决于精度需求和预算。
在该网站上查询北京的天气如下：
1.png

网站列出了8天的天气，本课的小程序的效果如下：
2.gif

本课示例代码来自《Delphi Cookbook》
你需要在该网站注册一个账号，然后申请一个免费的API Key，不过使用《Delphi Cookbook》作者的api key一样可以使用，但是这个示例调用的是旧版本的API，新版本的API已经进化到3.0，可以使用本课学到的知识打造一个真正有价值的世界天气预报应用程序。
3.png

2. 构建多设备应用程序。

1. 单击主菜单中的 File > New > Multi-Device Application - Delphi > Header/Footer ,创建一个新的多设备应用程序。
建议立即单击工具栏上的Save All按钮，将单元文件保存为MainFormU.pas，将项目保存为WeatherForecastEx.dproj。
项目结构应该像这样：
4.png

2.1 设置用户界面

用户界面大概按如下的步骤：

  • Header/Footer会自动添加Header和Footer两个TToolBar，在Header上面添加了一个名为HeaderLabel的TLabel控件,指定其Text属性为“天气预报小程序”。
  • 在Header上添加一个TAniIndictor控件，设置其Align属性为Right，这个控件将显示一个动态的指示器，提供用户运行中的反馈。
  • 在Header下面添加一个Align为Top的TPanel控件，在上面放2个TEdit，分别命名为EditCity和EditCountry，在最右侧放一个TButton控件，指定name属性为btnGetForecasts，将EditCity的Align设置为Client，EditCountry和btnGetForecasts的Align指定为Right。
  • 在Footer上放一个TLable控件，指定其name属性为lblInfo，用来显示一些系统消息。
  • 接下来放一个Align为Client的TListView控件，指定其ItemAppearance.ItemAppearance属性为Custom，将用来编程控制Item。
  • 最后，手一个TRestClient和TRestRequest控件到主窗体，指定TRestRequest.Client属性为TRestClient。
现在用户界面相关的控件已经准备好了。
5.png

2.2 测试天气预报服务

接下来，打开Delphi主菜单的 Tools >REST Debugger，
在弹出的窗口的第一页，Method指定为Get，在URL文本框上指定URL为：
http://api.openweathermap.org/data/2.5/forecast
Content-Type使用默认的Application/json
6.png

接下来切换到Parameters页，添加如下的键值对：
7.png

单击右上角的“Send Request”按钮，如果URL构建成功，则Response会返回200-OK状态，Response的Header区可以看到请求的头信息，Body区则可以看到具体的JSON数据。
8.png

通过分析JSON，可以得知应用程序将要提供哪些数据给用户，从而构建真正的用户界面。
9.png

整个JSON包含了一个list数组，每个数组里面的元素内容如下：

  • dt：Unix时间戳值。
  • main.temp_min：指定时间戳范围内的最低温度。
  • main.temp_max: 指定时间戳范围内的最高温度。
  • weather.main： 天气情况的英语表达。
  • weather.description：天气情况的本地语言表达。
3. 获取天气JSON数据，并进行JSON解析，生成用户界面

1. 在主窗体加载时，将会初始化RestClient和RESTRequest两个控件，FormCreate事件如下：
  1. // 主窗体创建时触发的事件处理过程
  2. procedure TMainForm.FormCreate(Sender: TObject);
  3. var
  4.   LocaleService: IFMXLocaleService;  // 声明一个FMX本地化服务接口变量
  5. begin
  6.   // 检查当前平台是否支持IFMXLocaleService接口
  7.   if TPlatformServices.Current.SupportsPlatformService(IFMXLocaleService) then
  8.   begin
  9.     // 获取FMX本地化服务接口实例
  10.     LocaleService := TPlatformServices.Current.GetPlatformService
  11.       (IFMXLocaleService) as IFMXLocaleService;
  12.       
  13.     // 获取当前系统的语言ID（例如："en-US"、"zh-CN"等）
  14.     Lang := LocaleService.GetCurrentLangID;
  15.   end
  16.   else
  17.     // 如果不支持本地化服务，则默认使用美国英语('US')
  18.     Lang := 'US';
  20.   // 设置国家/地区文本框默认值为中国('CN')
  21.   EditCountry.Text := 'CN';
  22.   
  23.   // 设置REST客户端的基础URL为OpenWeatherMap API地址
  24.   RESTClient1.BaseURL := 'http://api.openweathermap.org/data/2.5';
  25.   
  26.   // 设置REST请求的资源路径，包含参数占位符:
  27.   // {country} - 国家/地区代码
  28.   // {lang} - 语言代码
  29.   // {APPID} - API密钥
  30.   RESTRequest1.Resource :=
  31.     'forecast?q={country}&mode=json&lang={lang}&units=metric&APPID={APPID}';
  32.    
  33.   // 设置REST请求中的APPID参数值
  34.   RESTRequest1.Params.ParameterByName('APPID').Value := APPID;
  35.   
  36.   // 初始化时将活动指示器设置为不可见（不显示加载动画）
  37.   AniIndicator1.Visible := False;
  38. end;
复制代码
当访问一个RESTful服务器时，一般在TRESTClient控件中指定基本的URL，而查询字符串参数则在TRESTReuqest控件中指定。花括号内是查询字符串参数的占位和会，可以通过RESTRequest1.Params.ParameterByName这样的语法来进行设置。
2.为天气预报的刷新按钮添加事件处理代码，这里将使用标准的RESTRequest1.ExecuteAsync异步获取服务器端数据，获取完成后会执行一个匿名方法。
在这个事件处理代码中，调用了3个自定义的过程：
  1. // 在列表视图中添加日期分组标题项
  2. // 参数：
  3. //   AItems: 列表视图的项集合
  4. //   ADateStr: 要显示的日期字符串（格式为yyyy/mm/dd）
  5. procedure TMainForm.AddHeader(AItems: TListViewItems; const ADateStr: string);
复制代码
  1. // 在列表视图中添加单个天气预报项
  2. // 参数：
  3. //   AItems: 列表视图的项集合
  4. //   ADateTime: 预报日期时间
  5. //   ADescription: 天气描述（如"晴"、"多云"等）
  6. //   ATempMin: 最低温度
  7. //   ATempMax: 最高温度
  8. procedure TMainForm.AddForecastItem(AItems: TListViewItems;
  9.   ADateTime: TDateTime; const ADescription: string;
  10.   ATempMin, ATempMax: Double);
复制代码
  1. // 在列表视图中添加日期分组的汇总信息（当天温度极值）
  2. // 参数：
  3. //   AItems: 列表视图的项集合
  4. //   AMinTemp: 当天最低温度
  5. //   AMaxTemp: 当天最高温度
  6. procedure TMainForm.AddFooter(AItems: TListViewItems;
  7.   AMinTemp, AMaxTemp: Double);
复制代码
有了这些子程序的辅助，事件处理的代码就会相对简洁不少，完整的单击事件处理代码如下所示：
  1. // 获取天气预报按钮点击事件处理过程
  2. procedure TMainForm.btnGetForecastsClick(Sender: TObject);
  3. begin
  4.   // 清空列表视图中的所有项
  5.   ListView1.Items.Clear;
  6.   
  7.   // 设置REST请求中的country参数值，将城市和国家用逗号连接
  8.   RESTRequest1.Params.ParameterByName('country').Value :=
  9.     String.Join(',', [EditCity.Text, EditCountry.Text]);
  10.    
  11.   // 设置REST请求中的lang参数值，使用之前获取的语言ID
  12.   RESTRequest1.Params.ParameterByName('lang').Value := Lang;
  13.   
  14.   // 显示并启用活动指示器（加载动画）
  15.   AniIndicator1.Visible := True;
  16.   AniIndicator1.Enabled := True;
  17.   
  18.   // 禁用按钮防止重复点击
  19.   btnGetForecasts.Enabled := False;
  20.   
  21.   // 异步执行REST请求
  22.   RESTRequest1.ExecuteAsync(
  23.     procedure
  24.     var
  25.       LForecastDateTime: TDateTime;      // 预报日期时间
  26.       LJValue: TJSONValue;               // JSON值对象
  27.       LJObj, LMainForecast,             // JSON对象
  28.       LForecastItem, LJObjCity: TJSONObject;
  29.       LJArrWeather, LJArrForecasts: TJSONArray;  // JSON数组
  30.       LTempMin, LTempMax: Double;       // 最低和最高温度
  31.       LDay, LLastDay: string;           // 当前日期和上一个日期
  32.       LWeatherDescription: string;      // 天气描述
  33.       LAppRespCode: string;             // 应用响应代码
  34.       LMinInTheDay, LMaxInTheDay: Double; // 当天最低和最高温度
  36.     begin
  37.       try
  38.         // 将响应内容转换为JSON对象
  39.         LJObj := RESTRequest1.Response.JSONValue as TJSONObject;
  41.         // 检查错误响应
  42.         LAppRespCode := LJObj.GetValue('cod').Value;
  43.         if LAppRespCode.Equals('404') then
  44.         begin
  45.           // 城市未找到的错误处理
  46.           lblInfo.Text := '没有找到指定城市';
  47.           Exit;
  48.         end;
  49.         if not LAppRespCode.Equals('200') then
  50.         begin
  51.           // 其他错误处理
  52.           lblInfo.Text := '错误 ' + LAppRespCode;
  53.           Exit;
  54.         end;
  56.         // 解析天气预报数据
  57.         LMinInTheDay := 1000;    // 初始化当天最低温度为极大值
  58.         LMaxInTheDay := -LMinInTheDay; // 初始化当天最高温度为极小值
  59.         
  60.         // 获取预报列表数组
  61.         LJArrForecasts := LJObj.GetValue('list') as TJSONArray;
  62.         
  63.         // 遍历所有预报项
  64.         for LJValue in LJArrForecasts do
  65.         begin
  66.           // 获取单个预报项对象
  67.           LForecastItem := LJValue as TJSONObject;
  68.          
  69.           // 将Unix时间戳转换为Delphi日期时间
  70.           LForecastDateTime := UnixToDateTime((LForecastItem.GetValue('dt')
  71.             as TJSONNumber).AsInt64);
  72.             
  73.           // 获取主预报信息对象
  74.           LMainForecast := LForecastItem.GetValue('main') as TJSONObject;
  75.          
  76.           // 获取最低和最高温度
  77.           LTempMin := (LMainForecast.GetValue('temp_min')
  78.             as TJSONNumber).AsDouble;
  79.           LTempMax := (LMainForecast.GetValue('temp_max')
  80.             as TJSONNumber).AsDouble;
  81.             
  82.           // 获取天气描述数组
  83.           LJArrWeather := LForecastItem.GetValue('weather') as TJSONArray;
  84.          
  85.           // 获取第一个天气描述
  86.           LWeatherDescription := TJSONObject(LJArrWeather.Items[0])
  87.             .GetValue('description').Value;
  88.             
  89.           // 格式化日期为yyyy/mm/dd
  90.           LDay := FormatDateTime('yyyy/mm/dd', DateOf(LForecastDateTime));
  91.          
  92.           // 检查是否是新的日期
  93.           if LDay <> LLastDay then
  94.           begin
  95.             // 如果不是第一个日期，添加前一天的最高和最低温度的统计信息
  96.             if not LLastDay.IsEmpty then
  97.             begin
  98.               AddFooter(ListView1.Items, LMinInTheDay, LMaxInTheDay);
  99.             end;
  100.             
  101.             // 添加新日期的标题
  102.             AddHeader(ListView1.Items, LDay);
  103.             
  104.             // 重置当天温度极值
  105.             LMinInTheDay := 1000;
  106.             LMaxInTheDay := -LMinInTheDay;
  107.           end;
  108.          
  109.           // 保存当前日期供下次比较
  110.           LLastDay := LDay;
  111.          
  112.           // 更新当天最低和最高温度
  113.           LMinInTheDay := Min(LMinInTheDay, LTempMin);
  114.           LMaxInTheDay := Max(LMaxInTheDay, LTempMax);
  116.           // 添加预报项到列表视图
  117.           AddForecastItem(ListView1.Items, LForecastDateTime,
  118.             LWeatherDescription, LTempMin, LTempMax);
  119.         end; // 结束预报项遍历
  121.         // 添加最后一天的汇总信息
  122.         if not LLastDay.IsEmpty then
  123.           AddFooter(ListView1.Items, LMinInTheDay, LMaxInTheDay);
  125.         // 获取并显示城市和国家信息
  126.         LJObjCity := LJObj.GetValue('city') as TJSONObject;
  127.         lblInfo.Text := LJObjCity.GetValue('name').Value + ', ' +
  128.           LJObjCity.GetValue('country').Value;
  130.       finally
  131.         // 无论成功或失败，都执行以下清理操作
  132.         AniIndicator1.Visible := False;  // 隐藏活动指示器
  133.         AniIndicator1.Enabled := False;  // 禁用活动指示器
  134.         btnGetForecasts.Enabled := True; // 重新启用按钮
  135.       end;
  136.     end);
  137. end;
复制代码
代码的详细解说如下：

  • RESTRequest1.Params 是 TRESTRequest 组件中用于管理所有请求参数的集合属性，它允许你在发送 HTTP 请求前配置各种类型的参数,参数country配置为“城市，国家”，这是API的定义需求，直接写城市有时也能找到。
  • RESTRequest1.Response包含很多属性用来获取来自服务器的响应，如果服务器端返回JOSN数据，则使用JSONValue属性可以获取到JSON实例。
  • 服务器返回的JSON中包含了状态码，可以根据状态码判断查询成功还是失败。
  • 接下来对JSON中的list数组进行了解析，LMinInTheDay和LMinInTheDay 变量是统计1天中最高与最低温度的变量，在每天的日期发生变化后清零，在每天会进行Min与Max的统计运算。
  • 在每天的日期发生变化后，会调用AddHeader添加页眉，在添加页眉之前，总是会先对上一个日期结束位置调用AddFooter添加页脚。
  • 在最后一天也会添加一个页脚，避免遗漏。
  • 在每一天的日期记录中，调用AddForecastItem添加项。
  • 在代码最后为主窗体的footer区的TLabel控件也设置了显示文本。
接下来看看3个过程的具体实现，它们并未涉及到具体的显示位置等逻辑，这一切要在TListView的OnUpdateObject事件中完成。
  1. // 添加日期分组标题项到列表视图
  2. procedure TMainForm.AddHeader(AItems: TAppearanceListViewItems;
  3.   const ADay: String);
  4. var
  5.   LItem: TListViewItem;  // 声明列表项变量
  6. begin
  7.   // 在列表项集合中添加新项
  8.   LItem := AItems.Add;
  10.   // 设置该项为分组标题类型
  11.   LItem.Purpose := TListItemPurpose.Header;
  13.   // 在名为'HeaderLabel'的绘制对象中设置日期文本
  14.   LItem.Objects.FindDrawable('HeaderLabel').Data := ADay;
  15. end;
  17. // 添加单个天气预报项到列表视图
  18. procedure TMainForm.AddForecastItem(AItems: TAppearanceListViewItems;
  19.   const AForecastDateTime: TDateTime;  // 预报日期时间
  20.   const AWeatherDescription: String;   // 天气描述文本
  21.   const ATempMin, ATempMax: Double);   // 最低/最高温度
  22. var
  23.   LItem: TListViewItem;  // 声明列表项变量
  24. begin
  25.   // 在列表项集合中添加新项
  26.   LItem := AItems.Add;
  28.   // 设置'WeatherDescription'绘制对象的数据：
  29.   // 格式为"小时时+天气描述"（如"14时 多云"）
  30.   LItem.Objects.FindDrawable('WeatherDescription').Data :=
  31.     FormatDateTime('HH', AForecastDateTime) + '时  ' + AWeatherDescription;
  33.   // 设置'MinTemp'绘制对象的数据：
  34.   // 格式为"最低温度°"（如"12.50°"）
  35.   LItem.Objects.FindDrawable('MinTemp').Data :=
  36.     FormatFloat('#0.00', ATempMin) + '°';
  38.   // 设置'MaxTemp'绘制对象的数据：
  39.   // 格式为"最高温度°"（如"24.80°"）
  40.   LItem.Objects.FindDrawable('MaxTemp').Data :=
  41.     FormatFloat('#0.00', ATempMax) + '°';
  42. end;
  44. // 添加日期分组汇总信息到列表视图
  45. procedure TMainForm.AddFooter(AItems: TAppearanceListViewItems;
  46.   const LMinInTheDay, LMaxInTheDay: Double);  // 当日最低/最高温度
  47. var
  48.   LItem: TListViewItem;  // 声明列表项变量
  49. begin
  50.   // 在列表项集合中添加新项
  51.   LItem := AItems.Add;
  53.   // 设置该项为分组脚注类型
  54.   LItem.Purpose := TListItemPurpose.Footer;
  56.   // 设置脚注文本：
  57.   // 格式为"最低 XX.XX° 最高 XX.XX°"（如"最低 12.50° 最高 24.80°"）
  58.   LItem.Text := Format('最低 %2.2f° 最高 %2.2f°', [LMinInTheDay, LMaxInTheDay]);
  59. end;
复制代码
这里的过程仅负则添加和设置文本或Data数据，每一次AItems.Add过程调用之后，需要指定Purpose为具体的项类型，以便于OnUpdateObjects进行处理。
每次在Item.Txt或者是FindDrawable语句触发时，会自动调用OnUpdateObject来实现显示对象的真正呈现工作，事件处理代码如下：
  1. // 列表视图项更新事件处理过程
  2. procedure TMainForm.ListView1UpdateObjects(const Sender: TObject;
  3.   const AItem: TListViewItem);
  4. var
  5.   AQuarter: Double;     // 用于存储四分之一宽度的变量
  6.   lb: TListItemText;    // 列表项文本对象引用
  7.   lListView: TListView; // 列表视图引用
  8. begin
  9.   // 将Sender转换为TListView类型
  10.   lListView := Sender as TListView;
  11.   
  12.   // 根据列表项的目的类型进行不同处理
  13.   case AItem.Purpose of
  14.     // 处理普通列表项
  15.     TListItemPurpose.None:
  16.       begin
  17.         // 计算每列宽度（总宽度减去左右边距后分成4份）
  18.         AQuarter := (lListView.Width - lListView.ItemSpaces.Left -
  19.           lListView.ItemSpaces.Right) / 4;
  20.         
  21.         // 设置普通项的高度为24像素
  22.         AItem.Height := 24;
  24.         // 处理天气描述文本控件
  25.         lb := TListItemText(AItem.Objects.FindDrawable('WeatherDescription'));
  26.         if not Assigned(lb) then  // 如果对象不存在则创建
  27.         begin
  28.           lb := TListItemText.Create(AItem);    // 创建新文本对象
  29.           lb.PlaceOffset.X := 0;                // 设置X偏移为0
  30.           lb.TextAlign := TTextAlign.Leading;  // 文本左对齐
  31.           lb.Name := 'WeatherDescription';     // 设置对象名称
  32.         end;
  33.         lb.PlaceOffset.X := 0;  // 确保X偏移为0
  35.         // 处理最低温度文本控件
  36.         lb := TListItemText(AItem.Objects.FindDrawable('MinTemp'));
  37.         if not Assigned(lb) then  // 如果对象不存在则创建
  38.         begin
  39.           lb := TListItemText.Create(AItem);  // 创建新文本对象
  40.           lb.TextAlign := TTextAlign.Trailing;  // 文本右对齐
  41.           lb.TextColor := TAlphaColorRec.Blue;  // 设置文本颜色为蓝色
  42.           lb.Name := 'MinTemp';  // 设置对象名称
  43.         end;
  44.         lb.PlaceOffset.X := AQuarter * 2;  // 设置X位置为第二列
  45.         lb.Width := AQuarter;  // 设置宽度为四分之一宽度
  47.         // 处理最高温度文本控件
  48.         lb := TListItemText(AItem.Objects.FindDrawable('MaxTemp'));
  49.         if not Assigned(lb) then  // 如果对象不存在则创建
  50.         begin
  51.           lb := TListItemText.Create(AItem);  // 创建新文本对象
  52.           lb.TextAlign := TTextAlign.Trailing;  // 文本右对齐
  53.           lb.TextColor := TAlphaColorRec.Red;  // 设置文本颜色为红色
  54.           lb.Name := 'MaxTemp';  // 设置对象名称
  55.         end;
  56.         lb.PlaceOffset.X := AQuarter * 3;  // 设置X位置为第三列
  57.         lb.Width := AQuarter;  // 设置宽度为四分之一宽度
  58.       end;
  59.       
  60.     // 处理列表头项
  61.     TListItemPurpose.Header:
  62.       begin
  63.         // 设置头部高度为48像素
  64.         AItem.Height := 48;
  65.         
  66.         // 处理头部标签文本控件
  67.         lb := TListItemText(AItem.Objects.FindDrawable('HeaderLabel'));
  68.         if not Assigned(lb) then  // 如果对象不存在则创建
  69.         begin
  70.           lb := TListItemText.Create(AItem);  // 创建新文本对象
  71.           lb.TextAlign := TTextAlign.Center;  // 文本居中对齐
  72.           lb.Align := TListItemAlign.Center;  // 控件居中对齐
  73.           lb.TextColor := TAlphaColorRec.Red;  // 设置文本颜色为红色
  74.           lb.Name := 'HeaderLabel';  // 设置对象名称
  75.         end;
  76.         lb.PlaceOffset.Y := AItem.Height / 4;  // 设置Y偏移为高度的四分之一
  77.       end;
  78.       
  79.     // 处理列表脚注项
  80.     TListItemPurpose.Footer:
  81.       begin
  82.         // 设置脚注文本右对齐
  83.         AItem.Objects.TextObject.TextAlign := TTextAlign.Trailing;
  84.       end;
  85.   end;
  86. end;
复制代码
可以看到，在OnUpdateObject事件中，动态的创建了可绘制项元素，动态计算并设置其宽度和高度，所有与呈现相关的工作都在这个事件中得以完成。
总结

这篇文章主要分享了如下几个知识点：

  • 使用TRESTClient和TRESTResponse访问远程服务器，获取JSON数据源。
  • 使用System.JSON命名空间中的类解析JSON。
  • 根据JSON数据源动态创建列表项。
  • 处理OnUpdateObject事件创建列表项的呈现对象。
相信通过对这篇文章的学习，可以对TListView有较为深入的理解。

来源：程序园用户自行投稿发布，如果侵权，请联系站长删除
免责声明：如果侵犯了您的权益，请联系站长，我们会及时删除侵权内容，谢谢合作！

使用道具 举报
B Color Image Link Quote Code Smilies
您需要登录后才可以回帖 登录 | 立即注册
发帖
忙贬
2025-8-16 07:13:11

0

粉丝关注

20

主题发布

板块介绍填写区域，请于后台编辑
微信扫一扫